+AZ-LPT-100

pkgs/aider-chat-env/default.nix

@@ -0,0 +1,56 @@
+{
+  lib,
+  stdenv,
+  python3,
+  zlib,
+  libffi,
+  makeWrapper,
+}: let
+  pythonEnv = python3.withPackages (ps:
+    with ps; [
+      pip
+      virtualenv
+    ]);
+in
+  stdenv.mkDerivation rec {
+    pname = "aider-chat-env";
+    version = "0.1.0";
+
+    src = ./.;
+
+    nativeBuildInputs = [makeWrapper];
+    buildInputs = [pythonEnv zlib libffi];
+
+    installPhase = ''
+      mkdir -p $out/bin
+      cat > $out/bin/aider-chat-env <<EOF
+      #!/bin/sh
+      VENV_DIR="\$HOME/.aider-chat-venv"
+      if [ ! -d "\$VENV_DIR" ]; then
+        echo "Creating new virtual environment in \$VENV_DIR..."
+        ${pythonEnv}/bin/python -m venv "\$VENV_DIR"
+        source "\$VENV_DIR/bin/activate"
+        # Upgrade pip first
+        python -m pip install --no-cache-dir --upgrade pip
+        # Install aider-chat
+        python -m pip install --no-cache-dir aider-chat
+      else
+        source "\$VENV_DIR/bin/activate"
+      fi
+      exec "\$SHELL"
+      EOF
+      chmod +x $out/bin/aider-chat-env
+    '';
+
+    postFixup = ''
+      wrapProgram $out/bin/aider-chat-env \
+        --prefix PATH : ${lib.makeBinPath buildInputs} \
+        --prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [stdenv.cc.cc.lib zlib libffi]}
+    '';
+
+    meta = with lib; {
+      description = "Python environment with aider-chat";
+      license = licenses.mit;
+      platforms = platforms.all;
+    };
+  }

pkgs/code2prompt/default.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  pkg-config,
+  perl,
+  openssl,
+}:
+rustPlatform.buildRustPackage rec {
+  pname = "code2prompt";
+  version = "3.0.2";
+
+  src = fetchFromGitHub {
+    owner = "mufeedvh";
+    repo = "code2prompt";
+    rev = "v${version}";
+    hash = "sha256-9YbsrbExRFbsEz2GifklmUGp3YlsEUOi25+P5vPK8fs=";
+  };
+
+  cargoLock = {
+    lockFile = src + "/Cargo.lock";
+  };
+
+  buildAndTestSubdir = "crates/code2prompt";
+
+  nativeBuildInputs = [pkg-config perl];
+
+  buildInputs = [openssl];
+
+  meta = {
+    description = "A CLI tool that converts your codebase into a single LLM prompt with a source tree, prompt templating, and token counting";
+    homepage = "https://github.com/mufeedvh/code2prompt";
+    license = lib.licenses.mit;
+    mainProgram = "code2prompt";
+  };
+}

pkgs/default.nix

@@ -1,4 +1,10 @@
 {pkgs, ...}: {
   # Define your custom packages here
-  #  my-package = pkgs.callPackage ./my-package {};
+  hyprpaper-random = pkgs.callPackage ./hyprpaper-random {};
+  msty = pkgs.callPackage ./msty {};
+  msty-sidecar = pkgs.callPackage ./msty-sidecar {};
+  zellij-ps = pkgs.callPackage ./zellij-ps {};
+  aider-chat-env = pkgs.callPackage ./aider-chat-env {};
+  code2prompt = pkgs.callPackage ./code2prompt {};
+  pomodoro-timer = pkgs.callPackage ./pomodoro-timer {};
 }

pkgs/hyprpaper-random/default.nix

@@ -0,0 +1,72 @@
+{
+  lib,
+  stdenv,
+  writeShellScriptBin,
+  fd,
+  hyprland,
+  coreutils,
+  gawk,
+}: let
+  script = writeShellScriptBin "hyprpaper-random" ''
+    #!/usr/bin/env bash
+    set -euo pipefail
+
+    # Directory (override with WALLPAPER_DIR)
+    DIR="''${WALLPAPER_DIR:-''${XDG_CONFIG_HOME:-$HOME/.config}/hypr/wallpapers}"
+
+    HYPRCTL="${hyprland}/bin/hyprctl"
+    FD="${fd}/bin/fd"
+    SHUF="${coreutils}/bin/shuf"
+    TR="${coreutils}/bin/tr"
+    AWK="${gawk}/bin/awk"
+
+    # Pick one random image (null-safe)
+    WALLPAPER="$(
+      "$FD" . "$DIR" -t f -e jpg -e jpeg -e png -e webp -e avif -0 --follow --hidden \
+        | "$SHUF" -z -n1 \
+        | "$TR" -d '\0'
+    )"
+
+    if [[ -z "''${WALLPAPER:-}" ]]; then
+      echo "No wallpapers found in: $DIR" >&2
+      exit 1
+    fi
+
+    # Preload so hyprpaper can use it
+    "$HYPRCTL" hyprpaper preload "$WALLPAPER" >/dev/null 2>&1 || true
+
+    # Apply to all monitors
+    "$HYPRCTL" monitors \
+      | "$AWK" '/^Monitor /{print $2}' \
+      | while IFS= read -r mon; do
+          [ -n "$mon" ] && "$HYPRCTL" hyprpaper wallpaper "$mon,$WALLPAPER"
+        done
+
+    exit 0
+  '';
+in
+  stdenv.mkDerivation {
+    pname = "hyprpaper-random";
+    version = "0.1.1";
+
+    dontUnpack = true;
+
+    buildInputs = [
+      fd
+      hyprland
+      coreutils
+      gawk
+    ];
+
+    installPhase = ''
+      mkdir -p "$out/bin"
+      ln -s ${script}/bin/hyprpaper-random "$out/bin/hyprpaper-random"
+    '';
+
+    meta = with lib; {
+      description = "Minimal random wallpaper setter for Hyprpaper";
+      license = licenses.mit;
+      platforms = platforms.linux;
+      mainProgram = "hyprpaper-random";
+    };
+  }

pkgs/msty-sidecar/default.nix

@@ -0,0 +1,38 @@
+{
+  appimageTools,
+  fetchurl,
+  nodejs,
+  nodePackages,
+  uv,
+  python3,
+  makeWrapper,
+}: let
+  pname = "msty-sidecar";
+  version = "0.4.0";
+  src = fetchurl {
+    url = "https://sidecar-assets.msty.studio/prod/latest/linux/amd64/MstySidecar_x86_64_amd64.AppImage";
+    sha256 = "sha256-UhsokCG0NPqn5nhn//AaIuY6sWlZkejNlqMEyN4Opqg=";
+  };
+  appimageContents = appimageTools.extractType2 {inherit pname version src;};
+in
+  appimageTools.wrapType2 {
+    inherit pname version src;
+    nativeBuildInputs = [makeWrapper];
+
+    extraPkgs = pkgs: [
+      nodejs
+      nodePackages.npm
+      uv
+      python3
+    ];
+
+    extraInstallCommands = ''
+      install -m 444 -D ${appimageContents}/mstysidecar.desktop -t $out/share/applications
+      substituteInPlace $out/share/applications/mstysidecar.desktop \
+              --replace 'Exec=AppRun' 'Exec=${pname}'
+      install -m 444 -D ${appimageContents}/mstysidecar.png \
+              $out/share/icons/hicolor/256x256/apps/mstysidecar.png
+              wrapProgram $out/bin/${pname} \
+                      --prefix PATH : ${nodejs}/bin:${nodePackages.npm}/bin:${uv}/bin:${python3}/bin
+    '';
+  }

pkgs/msty/default.nix

@@ -0,0 +1,28 @@
+{
+  appimageTools,
+  fetchurl,
+  makeWrapper,
+}: let
+  pname = "msty";
+  version = "1.9.2";
+  src = fetchurl {
+    url = "https://assets.msty.app/prod/latest/linux/amd64/Msty_x86_64_amd64.AppImage";
+    sha256 = "sha256-Z4t0EcV9X4g5X0lBwipiMdP8lgPuBkhykAIKjHSUpnI=";
+  };
+  appimageContents = appimageTools.extractType2 {inherit pname version src;};
+in
+  appimageTools.wrapType2 {
+    inherit pname version src;
+
+    nativeBuildInputs = [makeWrapper];
+
+    extraInstallCommands = ''
+      install -m 444 -D ${appimageContents}/msty.desktop -t $out/share/applications
+      substituteInPlace $out/share/applications/msty.desktop \
+              --replace 'Exec=AppRun' 'Exec=${pname}'
+      install -m 444 -D ${appimageContents}/msty.png \
+              $out/share/icons/hicolor/256x256/apps/msty.png
+      wrapProgram $out/bin/${pname} \
+              --set XDG_CURRENT_DESKTOP GNOME
+    '';
+  }

pkgs/pomodoro-timer/default.nix

@@ -0,0 +1,92 @@
+{
+  lib,
+  stdenv,
+  writeShellScriptBin,
+  timer,
+  kitty,
+  rofi,
+  libnotify,
+  speechd,
+}: let
+  launcher = writeShellScriptBin "launch-timer" ''
+    #!/bin/bash
+
+    validate_time() {
+      local input=$1
+      if [[ $input =~ ^[0-9]+[mhs]$ ]]; then
+        return 0
+      else
+        return 1
+      fi
+    }
+
+    notify_end() {
+      local session_name=$1
+      ${libnotify}/bin/notify-send "Pomodoro" "$session_name session ended!"
+      ${speechd}/bin/spd-say "$session_name session ended"
+    }
+
+    start_timer() {
+      local duration=$1
+      local session_name=$2
+      kitty \
+        --class="floating-pomodoro" \
+        --title="floating-pomodoro" \
+        ${timer}/bin/timer $duration
+      notify_end "$session_name"
+    }
+
+    # Show rofi menu with options
+    selected=$(printf "work\nbreak\ncustom" | rofi -dmenu -p "Work Timer:" -l 3)
+
+    # Exit if no selection was made
+    [ -z "$selected" ] && exit
+
+    case $selected in
+      "work")
+        start_timer "45m" "work"
+        ;;
+      "break")
+        start_timer "10m" "break"
+        ;;
+      "custom")
+        # Show input dialog for custom time
+        custom_time=$(rofi -dmenu -p "Enter time (e.g., 25m, 1h, 30s):" -l 0)
+
+        # Validate input and start timer
+        if [ ! -z "$custom_time" ] && validate_time "$custom_time"; then
+          start_timer "$custom_time" "custom"
+        else
+          ${libnotify}/bin/notify-send "Invalid time format" "Please use format: 30s, 25m, or 1h"
+          exit 1
+        fi
+        ;;
+    esac
+  '';
+in
+  stdenv.mkDerivation {
+    pname = "work-timer";
+    version = "0.1.0";
+
+    dontUnpack = true;
+
+    buildInputs = [
+      timer
+      kitty
+      rofi
+      libnotify
+      speechd
+    ];
+
+    installPhase = ''
+      mkdir -p $out/bin
+      ln -s ${launcher}/bin/launch-timer $out/bin/launch-timer
+    '';
+
+    meta = with lib; {
+      description = "A Work timer.";
+      license = licenses.mit;
+      platforms = platforms.linux;
+      maintainers = [];
+    };
+  }

pkgs/zellij-ps/default.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitea,
+  fish,
+  fd,
+  fzf,
+  makeWrapper,
+  zellij,
+}:
+with lib;
+  stdenv.mkDerivation {
+    pname = "zellij-ps";
+    version = "0.1.0";
+
+    src = fetchFromGitea {
+      domain = "code.m3tam3re.com";
+      owner = "m3tam3re";
+      repo = "helper-scripts";
+      rev = "08a3217b83391c1110545c1ee3161eecd5dbe5e9";
+      sha256 = "1sc4i58mwcg3qsq0wwl5rvk08ykbxc497bq7mrxiirndsarskby7";
+    };
+
+    buildInputs = [];
+
+    nativeBuildInputs = [makeWrapper];
+    installPhase = ''
+      mkdir -p $out/bin
+      cp zellij-ps.fish $out/bin/zellij-ps
+      wrapProgram $out/bin/zellij-ps \
+        --prefix PATH : ${lib.makeBinPath [fish fd fzf zellij]}
+    '';
+
+    meta = with lib; {
+      description = "A small project script for zellij";
+      homepage = "https://code.m3tam3re.com/m3tam3re/helper-scripts";
+      license = licenses.mit;
+      maintainers = with maintainers; [m3tam3re];
+      platforms = platforms.unix;
+    };
+  }