+AZ-LPT-100

hosts/common/extraServices/default.nix

@@ -1,5 +1,8 @@
 {
   imports = [
+    ./flatpak.nix
+    ./ollama.nix
     ./podman.nix
+    ./virtualisation.nix
   ];
 }

hosts/common/extraServices/flatpak.nix

@@ -0,0 +1,24 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+with lib; let
+  cfg = config.extraServices.flatpak;
+in {
+  options.extraServices.flatpak.enable = mkEnableOption "enable flatpak";
+
+  config = mkIf cfg.enable {
+    services.flatpak.enable = true;
+    xdg.portal = {
+      # xdg desktop intergration (required for flatpak)
+      enable = true;
+      wlr.enable = true;
+      extraPortals = with pkgs; [
+        xdg-desktop-portal-hyprland
+      ];
+      config.common.default = "*";
+    };
+  };
+}

hosts/common/extraServices/ollama.nix

@@ -0,0 +1,32 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+with lib; let
+  cfg = config.extraServices.ollama;
+in {
+  options.extraServices.ollama.enable = mkEnableOption "enable ollama";
+
+  config = mkIf cfg.enable {
+    services.ollama = {
+      enable = true;
+      acceleration =
+        if config.services.xserver.videoDrivers == ["amdgpu"]
+        then "rocm"
+        else if config.services.xserver.videoDrivers == ["nvidia"]
+        then "cuda"
+        else null;
+      host = "[::]";
+      openFirewall = true;
+      environmentVariables = {
+        OLLAMA_HOST = "0.0.0.0";
+      };
+    };
+    nixpkgs.config = {
+      rocmSupport = config.services.xserver.videoDrivers == ["amdgpu"];
+      cudaSupport = config.services.xserver.videoDrivers == ["nvidia"];
+    };
+  };
+}

hosts/common/extraServices/virtualisation.nix

@@ -0,0 +1,52 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+with lib; let
+  cfg = config.extraServices.virtualisation;
+in {
+  options.extraServices.virtualisation.enable = mkEnableOption "enable virtualisation";
+
+  config = mkIf cfg.enable {
+    virtualisation = {
+      libvirtd = {
+        enable = true;
+        qemu = {
+          package = pkgs.qemu_kvm;
+          runAsRoot = true;
+          swtpm.enable = true;
+          ovmf = {
+            enable = true;
+            packages = [
+              (pkgs.OVMF.override {
+                secureBoot = true;
+                tpmSupport = true;
+              })
+              .fd
+            ];
+          };
+        };
+      };
+    };
+    programs.virt-manager.enable = true;
+    environment = {
+      systemPackages = [pkgs.qemu];
+      etc = {
+        "ovmf/OVMF_CODE.fd" = {
+          source = "${(pkgs.OVMF.override {
+            secureBoot = true;
+            tpmSupport = true;
+          }).fd}/FV/OVMF_CODE.fd";
+        };
+        "ovmf/OVMF_VARS.fd" = {
+          source = "${(pkgs.OVMF.override {
+            secureBoot = true;
+            tpmSupport = true;
+          }).fd}/FV/OVMF_VARS.fd";
+        };
+      };
+    };
+  };
+}